Overblog Suivre ce blog
Editer l'article Administration Créer mon blog
17 février 2008 7 17 /02 /février /2008 15:31

Le filtre Laguerre.


Dans le document "Time Warp Without Space Travel", téléchargeable sur le site mesasoftware.com, J. Ehlers (arriverais-je à en faire le tour ?) présente le filtre Laguerre.  Voici une vue  du future DAX avec un coéfficient  de 0.8 :

hk91.gif


Un filtre FIR est ajouté pour comparaison, un coéfficient de 0 rend le filtre Laguerre identique au filtre FIR.


Voici le code pour Prorealtime, il faut mettre gamma en variable :

pr=medianprice
once l0=pr
once l1=pr
once l2=pr
once l3=pr
if barindex>0 then
    l0=(1-gamma)*pr+gamma*l0[1]
    l1=-gamma*l0+l0[1]+gamma*l1[1]
    l2=-gamma*l1+l1[1]+gamma*l2[1]
    l3=-gamma*l2+l2[1]+gamma*l3[1]
endif
filtre=(l0+2*l1+2*l2+l3)/6
fir=(pr+2*pr[1]+2*pr[2]+pr[3])/6

return filtre,fir

Le Laguerre RSI.

Dans le même document, Ehlers présente également le Laguerre RSI qui d'après l'auteur, donne de très bons signaux.  L'indicateur a l'air populaire sur le Forex comme en témoigne ce système.  Voici une vue de l'EURUSD avec l'indicateur (coéfficient 0.5) :

hk92.gif

Les signaux d'achat sont donnés par un croisement à la hause de la ligne 0.2 et les signaux de vente par un croisement de la ligne 0.8 à la baisse.  On peut faire varier ces différents niveaux ainsi que le coéfficient, tout cela à backtester bien évidemment.

Voici le code pour Prorealtime, il faut toujours introduire gamma en variable :

pr=medianprice
once l0=pr
once l1=pr
once l2=pr
once l3=pr
once rsil=undefined
if barindex>0 then
    l0=(1-gamma)*pr+gamma*l0[1]
    l1=-gamma*l0+l0[1]+gamma*l1[1]
    l2=-gamma*l1+l1[1]+gamma*l2[1]
    l3=-gamma*l2+l2[1]+gamma*l3[1]
    cu=0
    cd=0
    if l0>=l1 then
        cu=l0-l1
    else
        cd=l1-l0
    endif
    if l1>=l2 then
        cu=cu+l1-l2
    else
        cd=cd+l2-l1
    endif
    if l2>=l3 then
        cu=cu+l2-l3
    else
        cd=cd+l3-l2
    endif
    rsil=cu/(cu+cd)
endif

return rsil,0.2,0.8

sbug_fck

Partager cet article

Repost 0
Published by hk_lisse - dans Indicateurs
commenter cet article

commentaires